!if $wims_read_parm!=slib_header
  !goto proc
!endif
slib_title=Pavage hyperbolique du disque de Poincar par des triangles
slib_author=Bernadette, Perrin-Riou
slib_parms=3\
,[p,q,r]\
100,borne\
size=600 color=[black,white],option (mots) : size= color=[] precision= html/url

slib_out=dessin donn par un fichier de type presque off (en dimension 2).

slib_comment=

ce n'est pas tout  fait off: rajouter un 0 pour avoir trois composantes dans les points
Il manque aussi la ligne sur le nombre de sommets faces aretes
slib_example=[5,6,7],120,precision=8 html\
[5,5,5],,color=[red,blue] html\
[3,3,4],,size=800 html\
[4,5,3],120,html\
[5,4,3],120,html\
[3,4,6],100,url\
[3,4,5]
!exit

:proc
!reset slib_precicion slib_size slib_color
!distribute items $wims_read_parm into slib_data,slib_bound,slib_option
!default slib_bound=100
!set slib_size=!getopt size in $slib_option
!default slib_size=600
!set slib_color=!getopt color in $slib_option
!set slib_color=!declosing $slib_color
!default slib_color=black,white
!set slib_precision=!getopt precision in $slib_option
!default slib_precision=4
!set wims_multiexec=$wims_multiexec pari
!if $slib_header_cox=
  !readproc gp/coxhyp.gp
!endif
!set slib_coxhyp=!exec pari default(realprecision,$slib_precision); $slib_header_cox;

!set slib_pqr=!declosing $slib_data
!set slib_coxhyp=!exec pari hyp3($slib_pqr,$slib_bound)
!reset slib_dessin
!set slib_data=!trim $slib_coxhyp
!set slib_data=!declosing $slib_data
!distribute items $slib_data into slib_pts, slib_tris
slib_pts=!declosing $slib_pts
slib_tris=!declosing $slib_tris
slib_tricnt=!rowcnt $slib_tris

!for slib_k=1 to $slib_tricnt
  !set slib_tri=$(slib_tris[$slib_k;])
  !set slib_col=$(slib_color[1+$(slib_tri[4])])
  !set slib_dessin=!append line fhyptriangle $(slib_pts[$(slib_tri[1]);]),$(slib_pts[$(slib_tri[2]);]),$(slib_pts[$(slib_tri[3]);]),$slib_col to $slib_dessin
!next
!set slib_range=-1,1
slib_out=xrange $slib_range\
yrange $slib_range\
fcircles lightgrey,0,0,1\
$slib_dessin

!if url iswordof $slib_option or html iswordof $slib_option
  !set insdraw_size=$slib_size,$slib_size
  !insdraw $slib_out
  slib_out=$ins_url
  !if html iswordof $slib_option
    slib_out=<img src="$ins_url" alt="">
  !else
    slib_out=$slib_out,$insdraw_size
  !endif
!endif

